cairo/PKGBUILD

# This is an example PKGBUILD file. Use this as a start to creating your own,
# and remove these comments. For more information, see 'man PKGBUILD'.
# NOTE: Please fill out the license field for your package! If it is unknown,
# then please put 'unknown'.

# Maintainer: Future Linux Team <future_linux@163.com>
pkgname=(cairo cairo-docs)
pkgbase=cairo
pkgver=1.18.2
pkgrel=1
pkgdesc="2D graphics library with support for multiple output devices"
arch=('x86_64')
url="https://cairographics.org"
license=('LGPL-2.1-only OR MPL-1.1')
depends=(
    'bash'
    'fontconfig'
    'freetype2'
    'glib2'
    'glibc'
    'libpng'
    'libx11'
    'libxcb'
    'libxext'
    'libxrender'
    'lzo'
    'pixman'
    'zlib')
makedepends=('meson' 'gtk-doc' 'valgrind')
source=(https://www.cairographics.org/releases/${pkgname}-${pkgver}.tar.xz)
sha256sums=(a62b9bb42425e844cc3d6ddde043ff39dbabedd1542eba57a2eb79f85889d45a)

build() {
    cd ${pkgname}-${pkgver}

    ${FUTURE_MESON}              \
        -Ddwrite=disabled        \
        -Dgtk_doc=true           \
        -Dspectre=disabled       \
        -Dsymbol-lookup=disabled \
        -Dtests=disabled

    meson compile -C build
}

package_cairo() {
    options+=(!emptydirs)

    cd ${pkgname}-${pkgver}

    meson install -C build --destdir ${pkgdir}

    _pick doc ${pkgdir}/usr/share/gtk-doc
}

package_cairo-docs() {
    pkgdesc+=" (documentation)"
    depends=()

    mv doc/* ${pkgdir}
}