# This is an example PKGBUILD file. Use this as a start to creating your own,
# and remove these comments. For more information, see 'man PKGBUILD'.
# NOTE: Please fill out the license field for your package! If it is unknown,
# then please put 'unknown'.

# Maintainer: Future Linux Team <future_linux@163.com>
pkgname=cpio
pkgver=2.15
pkgrel=1
pkgdesc="A tool to copy files into or out of a cpio or tar archive"
arch=('x86_64')
url="https://www.gnu.org/software/cpio"
license=('GPL-3.0-or-later')
depends=('glibc')
source=(https://ftp.gnu.org/gnu/${pkgname}/${pkgname}-${pkgver}.tar.gz)
sha256sums=(efa50ef983137eefc0a02fdb51509d624b5e3295c980aa127ceee4183455499e)

build() {
    cd ${pkgname}-${pkgver}

    ${CONFIGURE}             \
        --enable-mt          \
        --with-rmt=/usr/libexec/rmt

    make
    makeinfo --html            -o doc/html      doc/cpio.texi
    makeinfo --html --no-split -o doc/cpio.html doc/cpio.texi
    makeinfo --plaintext       -o doc/cpio.txt  doc/cpio.texi
}

package() {
    cd ${pkgname}-${pkgver}

    make DESTDIR=${pkgdir} install

    install -v -m755 -d ${pkgdir}/usr/share/doc/${pkgname}-${pkgver}/html
    install -v -m644    doc/html/* ${pkgdir}/usr/share/doc/${pkgname}-${pkgver}/html
    install -v -m644    doc/cpio.{html,txt} ${pkgdir}/usr/share/doc/${pkgname}-${pkgver}

}