filesystem/PKGBUILD

# This is an example PKGBUILD file. Use this as a start to creating your own,
# and remove these comments. For more information, see 'man PKGBUILD'.
# NOTE: Please fill out the license field for your package! If it is unknown,
# then please put 'unknown'.

# Maintainer: Future Linux Team <future_linux@163.com>
pkgname=filesystem
pkgver=20240401
pkgrel=1
pkgdesc="Base Future Linux files"
arch=('x86_64')
url="https://futurelinux.github.io/"
license=('GPL-3.0-or-later')
groups=('base')
depends=('iana-etc')
backup=(etc/fstab
	etc/group
	etc/hostname
	etc/hosts
	etc/issue
	etc/locale.conf
	etc/os-release
	etc/passwd)
source=(fstab
	group
	hostname
	hosts
	issue
	locale.conf
	os-release
	passwd)
sha256sums=(45d48dd125685c737136fc3deae94887bbdba46a5fb59244fb1ffb39cadb6620
	005ef4e65e0f761e5d0f4b707c7f288e2492681cfe9835ff8caa8edfc33c1bc2
	26520c981703c1ddc64c417d40861ec8e609df0db3de89a839fdf5f7aca87c03
	13cb6513d6484f27053868f8f8f106b50386e406c7fd75fa98a7642ecd69c5dd
	373af47d05b3b895092f43ed895d4680e0127627c05f2187d56794d2f1a43a57
	0328593405c8c79ba4677a7d227cff0af65fcf4e6fde227bd80762900bf2cd80
	ce9a337dda498168a2e372402fcebe090ba9a0908c5073d22622c945d5245635
	7817ee628fccd203d7f1bcc20f0afbbaaae615b5bc900314995da35764df0b47)

package() {

	install -vdm755 ${pkgdir}/{boot,dev,etc,home,mnt,usr/{bin,lib,lib64,sbin},var,opt,srv}

	install -vdm0555 ${pkgdir}/{proc,sys}

	install -vdm0750 ${pkgdir}/root

	install -vdm1777 ${pkgdir}/{tmp,run} ${pkgdir}/var/tmp

	install -vdm755 ${pkgdir}/etc/{opt,sysconfig}
	install -vdm755 ${pkgdir}/usr/lib/firmware
	install -vdm755 ${pkgdir}/media/{floppy,cdrom}
	install -vdm755 ${pkgdir}/usr/{,local/}{include,src}
	install -vdm755 ${pkgdir}/usr/local/{bin,lib,lib64,sbin}
	install -vdm755 ${pkgdir}/usr/{,local/}share/{color,dict,doc,info,locale,man}
	install -vdm755 ${pkgdir}/usr/{,local/}share/{misc,terminfo,zoneinfo}
	install -vdm755 ${pkgdir}/usr/{,local/}share/man/man{1..8}
	install -vdm755 ${pkgdir}/var/{cache,local,log,mail,opt,spool}
	install -vdm755 ${pkgdir}/var/lib/{color,misc,locate}

	ln -sfv /run ${pkgdir}/var/run
	ln -sfv /run/lock ${pkgdir}/var/lock

	for L in bin lib lib64 sbin; do
		ln -sv usr/${L} ${pkgdir}/${L}
	done

	ln -sfv /proc/self/mounts ${pkgdir}/etc/mtab

	touch ${pkgdir}/var/log/{btmp,lastlog,faillog,wtmp}
	chgrp -v 13   ${pkgdir}/var/log/lastlog
	chmod -v 664  ${pkgdir}/var/log/lastlog
	chmod -v 600  ${pkgdir}/var/log/btmp

	for F in fstab group hostname hosts issue locale.conf passwd os-release; do
		install -m644 ${srcdir}/${F} ${pkgdir}/etc/
	done

	touch ${pkgdir}/etc/future-release
}