gnupg/PKGBUILD

# This is an example PKGBUILD file. Use this as a start to creating your own,
# and remove these comments. For more information, see 'man PKGBUILD'.
# NOTE: Please fill out the license field for your package! If it is unknown,
# then please put 'unknown'.

# Maintainer: Future Linux Team <future_linux@163.com>
pkgname=gnupg
pkgver=2.4.5
pkgrel=2
pkgdesc="Complete and free implementation of the OpenPGP standard"
arch=('x86_64')
url="https://www.gnupg.org/"
license=('BSD-2-Clause'
    'BSD-3-Clause'
    'BSD-4-Clause'
    'CC0-1.0'
    'GPL-2.0-or-later'
    'GPL-3.0-or-later'
    'LGPL-2.1-or-later'
    'LGPL-3.0-or-later OR GPL-2.0-or-later'
    'MIT'
    'Unicode-TOU')
depends=(
    'glibc'
    'bzip2'
    'zlib'
    'bash'
    'readline'
    'libassuan'
    'libgcrypt'
    'libksba'
    'npth'
    'libldap'
    'gnutls'
    'pinentry'
    'libgpg-error'
    'sqlite'
    'libusb')
source=(https://www.gnupg.org/ftp/gcrypt/${pkgname}/${pkgname}-${pkgver}.tar.bz2)
sha256sums=(f68f7d75d06cb1635c336d34d844af97436c3f64ea14bcb7c869782f96f44277)

build() {
    cd ${pkgname}-${pkgver}

    mkdir build
    cd    build

    ${BUILD_CONFIGURE}          \
        --localstatedir=/var    \
        --sysconfdir=/etc       \
        --docdir=/usr/share/doc/${pkgname}-${pkgver}

    make
    makeinfo --html --no-split -I doc -o doc/gnupg_nochunks.html ../doc/gnupg.texi
    makeinfo --plaintext       -I doc -o doc/gnupg.txt           ../doc/gnupg.texi
    make -C doc html
}

package() {
    cd ${pkgname}-${pkgver}/build

    make DESTDIR=${pkgdir} install

    install -v -m755 -d ${pkgdir}/usr/share/doc/${pkgname}-${pkgver}/html
    install -v -m644    doc/gnupg_nochunks.html ${pkgdir}/usr/share/doc/${pkgname}-${pkgver}/html/gnupg.html
    install -v -m644    ../doc/*.texi doc/gnupg.txt ${pkgdir}/usr/share/doc/${pkgname}-${pkgver}
    install -v -m644    doc/gnupg.html/* ${pkgdir}/usr/share/doc/${pkgname}-${pkgver}/html
}