# This is an example PKGBUILD file. Use this as a start to creating your own,
# and remove these comments. For more information, see 'man PKGBUILD'.
# NOTE: Please fill out the license field for your package! If it is unknown,
# then please put 'unknown'.

# Maintainer: Future Linux Team <future_linux@163.com>
pkgname=(gobject-introspection gobject-introspection-runtime libgirepository)
pkgbase=gobject-introspection
pkgver=1.82.0
_glibver=2.82.2
pkgrel=1
pkgdesc="Introspection system for GObject-based libraries"
arch=('x86_64')
url="https://wiki.gnome.org/Projects/GObjectIntrospection"
license=('GPL-2.0-or-later' 'LGPL-2.0-or-later')
makedepends=(
    "glib2=${_glibver}"
    'cairo'
    'glibc'
    'git'
    'gtk-doc'
    'libffi'
    'meson'
    'python'
    'python-mako'
    'python-markdown'
    'python-setuptools'
    'python-sphinx'
)
source=(git+https://github.com/GNOME/gobject-introspection.git#tag=${pkgver}
    git+https://github.com/GNOME/glib.git#tag=${_glibver}
    git+https://github.com/GNOME/gobject-introspection-tests.git)
sha256sums=(SKIP
    SKIP
    SKIP)

prepare() {
    cd ${pkgbase}

    git submodule init
    git submodule set-url gobject-introspection-tests ${srcdir}/gobject-introspection-tests
    git -c protocol.file.allow=always -c protocol.allow=never submodule update
}

build() {
    cd ${pkgbase}

    meson setup build         \
        --prefix=/usr         \
        -Dbuildtype=release   \
        -Dlibdir=/usr/lib64   \
        -Dgtk_doc=true        \
        -Dglib_src_dir=${srcdir}/glib

    meson compile -C build
}

package_gobject-introspection() {
    depends=(
        "gobject-introspection-runtime=${pkgver}-${pkgrel}"
        "libgirepository=${pkgver}-${pkgrel}"
        'glib2'
        'glibc'
        'libffi'
        'python'
        'python-mako'
        'python-markdown'
        'python-setuptools'
    )
    
    cd ${pkgbase}

    meson install -C build --destdir ${pkgdir}

    python3 -m compileall -d /usr/lib64/${pkgbase} ${pkgdir}/usr/lib64/${pkgbase}
    python3 -O -m compileall -d /usr/lib64/${pkgbase} ${pkgdir}/usr/lib64/${pkgbase}

    _pick libg ${pkgdir}/usr/include/gobject-introspection-1.0
    _pick libg ${pkgdir}/usr/lib64/libgirepository-1.0.so*
    _pick libg ${pkgdir}/usr/lib64/pkgconfig/gobject-introspection*-1.0.pc
    _pick libg ${pkgdir}/usr/lib64/girepository-1.0/GIRepository-2.0.typelib
    _pick libg ${pkgdir}/usr/share/gir-1.0/GIRepository-2.0.gir
    _pick libg ${pkgdir}/usr/share/gtk-doc

    _pick runtime ${pkgdir}/usr/lib64/girepository-1.0
}

package_gobject-introspection-runtime() {
    pkgdesc+=" - runtime"
    depends=("libgirepository=${pkgver}-${pkgrel}")

    mv runtime/* ${pkgdir}
}

package_libgirepository() {
    pkgdesc+=" - runtime library"
    depends=('glib2' 'glibc' 'libffi')

    mv libg/* ${pkgdir}
}