keyutils/PKGBUILD

# This is an example PKGBUILD file. Use this as a start to creating your own,
# and remove these comments. For more information, see 'man PKGBUILD'.
# NOTE: Please fill out the license field for your package! If it is unknown,
# then please put 'unknown'.

# Maintainer: Future Linux Team <future_linux@163.com>
pkgname=keyutils
pkgver=1.6.3
pkgrel=2
pkgdesc="Linux Key Management Utilities"
arch=('x86_64')
url="https://www.kernel.org"
license=('GPL2' 'LGPL2.1')
depends=('glibc' 'bash')
backup=(etc/request-key.conf)
source=(https://git.kernel.org/pub/scm/linux/kernel/git/dhowells/${pkgname}.git/snapshot/${pkgname}-${pkgver}.tar.gz
    request-key.conf.patch
    reproducible.patch)
sha256sums=(a61d5706136ae4c05bd48f86186bcfdbd88dd8bd5107e3e195c924cfc1b39bb4
    539b163178fea41d645ae01bd1c74d9c6f6a92f3094df7cb3ed487a0f7f8b15b
    7bb7400b2b8c8f0288c86ec9191f8964a1e682745a204013d5fc7c2e1a253d8e)

prepare() {
    cd ${pkgname}-${pkgver}

    # fix paths of binaries in /etc/request-key.conf
    patch -Np0 -i ${srcdir}/request-key.conf.patch

    # make keyutils reproducible
    patch -Np1 -i ${srcdir}/reproducible.patch
}

build() {
    cd ${pkgname}-${pkgver}

    make CFLAGS="${CFLAGS}" LDFLAGS="${LDFLAGS}" LIBDIR=/usr/lib64 SBINDIR=/usr/sbin BINDIR=/usr/bin
}

package() {
	cd ${pkgname}-${pkgver}

	make DESTDIR=${pkgdir} NO_ARLIB=1 LIBDIR=/usr/lib64 BINDIR=/usr/bin SBINDIR=/usr/sbin install
}