# This is an example PKGBUILD file. Use this as a start to creating your own,
# and remove these comments. For more information, see 'man PKGBUILD'.
# NOTE: Please fill out the license field for your package! If it is unknown,
# then please put 'unknown'.

# Maintainer: Future Linux Team <future_linux@163.com>
pkgname=libfido2
pkgver=1.15.0
pkgrel=1
pkgdesc="Library functionality for FIDO 2.0, including communication with a device over USB"
arch=('x86_64')
url="https://developers.yubico.com/libfido2"
license=('BSD-2-Clause')
depends=('glibc' 'openssl' 'libcbor' 'hidapi' 'systemd' 'zlib')
makedepends=('cmake')
source=(https://developers.yubico.com/libfido2/Releases/${pkgname}-${pkgver}.tar.gz)
sha256sums=(abaab1318d21d262ece416fb8a7132fa9374bda89f6fa52b86a98a2f5712b61e)

prepare() {
    cd ${pkgname}-${pkgver}

    sed -i 's,-Werror,& -Wno-error=conversion,' CMakeLists.txt
}

build() {
    cd ${pkgname}-${pkgver}

    cmake -Bbuild                             \
          -DCMAKE_INSTALL_PREFIX=/usr         \
          -DCMAKE_INSTALL_LIBDIR=lib64        \
          -DCMAKE_BUILD_TYPE=none             \
          -Wno-dev

    make -C build VERBOSE=1
}

package() {
    cd ${pkgname}-${pkgver}

    make -C build DESTDIR=${pkgdir} install
}