lmdb/PKGBUILD

# This is an example PKGBUILD file. Use this as a start to creating your own,
# and remove these comments. For more information, see 'man PKGBUILD'.
# NOTE: Please fill out the license field for your package! If it is unknown,
# then please put 'unknown'.

# Maintainer: Future Linux Team <future_linux@163.com>
pkgname=lmdb
pkgver=0.9.33
pkgrel=1
pkgdesc="Symas Lightning Memory-Mapped Database"
arch=('x86_64')
url="https://symas.com/lmdb"
license=('custom:OpenLDAP')
depends=('glibc')
makedepends=('git')
options=('!emptydirs')
source=(git+https://git.openldap.org/openldap/openldap.git#tag=LMDB_${pkgver}
    lmdb.pc)
sha256sums=(SKIP
    84773d232ee0a11a307ed4374fc4cbf8d6ea1b0feeb3ee9499fe821e4b98a28f)

prepare() {

    sed -e "s|@PKGVER@|$pkgver|" -i lmdb.pc
}

build() {
    cd openldap/libraries/liblmdb

    make CFLAGS="$CFLAGS" CPPFLAGS="$CPPFLAGS" LDFLAGS="$LDFLAGS" prefix=/usr libdir=/usr/lib64
}

package() {
    cd openldap/libraries/liblmdb

    install -dm755 ${pkgdir}/usr/{bin,lib64,include,man/man1,share}

    make DESTDIR=${pkgdir} prefix=/usr libdir=/usr/lib64 install

    mv ${pkgdir}/usr/man ${pkgdir}/usr/share/man

    install -Dm644 ${srcdir}/lmdb.pc -t ${pkgdir}/usr/lib64/pkgconfig/
}