# This is an example PKGBUILD file. Use this as a start to creating your own,
# and remove these comments. For more information, see 'man PKGBUILD'.
# NOTE: Please fill out the license field for your package! If it is unknown,
# then please put 'unknown'.

# Maintainer: Future Linux Team <future_linux@163.com>
pkgname=pacman
pkgver=7.0.0.r3.g7736133
_git_tag=7.0.0
_git_patch_level_commit=77361331ae3864c6ea880e715c5864d59336f275
pkgrel=1
pkgdesc="A library-based package manager with dependency support"
arch=('x86_64')
url="https://www.archlinux.org/pacman/"
license=('GPL-2.0-or-later')
groups=('base' 'base-devel')
depends=(
    'bash'
    'coreutils'
    'curl'
    'gawk'
    'gettext'
    'glibc'
    'gnupg'
    'gpgme'
    'grep'
    'libarchive'
    'systemd'
    'zstd')
makedepends=('doxygen' 'git' 'meson' 'python-asciidoc')
backup=(etc/pacman.conf
    etc/makepkg.conf
    etc/makepkg.conf.d/future-build.conf
    etc/makepkg.conf.d/rust.conf
    etc/pacman.d/mirrorlist)
source=(git+https://gitlab.archlinux.org/pacman/pacman.git#tag=v${_git_tag}
    revertme-makepkg-remove-libdepends-and-libprovides.patch::https://gitlab.archlinux.org/pacman/pacman/-/commit/354a300cd26bb1c7e6551473596be5ecced921de.patch
    future-build.conf
    makepkg.conf
    pacman.conf
    rust.conf
    mirrorlist)
sha256sums=(SKIP
    b3bce9d662e189e8e49013b818f255d08494a57e13fc264625f852f087d3def2
    58ad3c7e09e86a6f493a00235a34d09adc9bdedcab2f4731463074ed7bbe992b
    128c4737dedd58e0b0ffec306feaf1752260591b1222bdcb32c22bcaf8a8a44a
    f6faafd6691a2b11e98996ff09500803ade4d0e943e7bff08c59e4e42b171da5
    851385788fcef9eba37c7b9403d0010ccc94800b3279bc60ab5fcabc6ee8d321
    6c5163c174d451fb42f86670f99343782d736db1c3304f4e043452dc0eec3125)

pkgver() {
    cd ${pkgname}

    git describe --abbrev=7 --match 'v*' | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
    cd ${pkgname}

    # apply patch level commits on top of annotated tag
    if [[ -n ${_git_patch_level_commit} ]]; then
        if [[ v${_git_tag} != $(git describe --tags --abbrev=0 "${_git_patch_level_commit}") ]] then
            error "patch level commit ${_git_patch_level_commit} is not a descendant of v${_git_tag}"
            exit 1
        fi
        git rebase "${_git_patch_level_commit}"
    fi

    patch -RNp1 < ${srcdir}/revertme-makepkg-remove-libdepends-and-libprovides.patch

}

build() {
    cd ${pkgname}

    ${FUTURE_MESON}                       \
          -Dpkg-ext=".pkg.tar.zst"        \
          -Dsrc-ext=".src.tar.zst"        \
          -Dcrypto=openssl                \
          -Ddoc=enabled                   \
          -Dscriptlet-shell=/usr/bin/bash \
          -Dldconfig=/usr/sbin/ldconfig

    meson compile -C build
}

package() {
    cd ${pkgname}

    meson install -C build --destdir ${pkgdir}

    install -m644 ${srcdir}/makepkg.conf ${pkgdir}/etc
    install -m644 ${srcdir}/pacman.conf  ${pkgdir}/etc
    install -vm644 ${srcdir}/future-build.conf ${pkgdir}/etc/makepkg.conf.d
    install -vm644 ${srcdir}/rust.conf ${pkgdir}/etc/makepkg.conf.d
    install -vDm644 ${srcdir}/mirrorlist ${pkgdir}/etc/pacman.d/mirrorlist
}