python-docutils/PKGBUILD

# This is an example PKGBUILD file. Use this as a start to creating your own,
# and remove these comments. For more information, see 'man PKGBUILD'.
# NOTE: Please fill out the license field for your package! If it is unknown,
# then please put 'unknown'.

# Maintainer: Future Linux Team <future_linux@163.com>
pkgname=python-docutils
pkgver=0.21.2
pkgrel=1
pkgdesc="Set of tools for processing plaintext docs into formats such as HTML, XML, or LaTeX"
arch=('x86_64')
url="http://docutils.sourceforge.net"
license=('custom')
depends=('python')
makedepends=('python-build' 'python-installer' 'python-flit-core')
source=(https://files.pythonhosted.org/packages/source/d/${pkgname#*-}/${pkgname#*-}-${pkgver}.tar.gz)
sha256sums=(3a6b18732edf182daa3cd12775bbb338cf5691468f91eeeb109deff6ebfa986f)

prepare() {
    cd ${pkgname#*-}-${pkgver}

    # Remove include list https://github.com/pypa/wheel/issues/92
    sed -i '/^include =/,/]/d' pyproject.toml
}

build() {
    cd ${pkgname#*-}-${pkgver}

    python3 -m build --wheel --skip-dependency-check --no-isolation
}

package() {
    cd ${pkgname#*-}-${pkgver}

    python3 -m installer --destdir=${pkgdir} dist/*.whl
}