# This is an example PKGBUILD file. Use this as a start to creating your own,
# and remove these comments. For more information, see 'man PKGBUILD'.
# NOTE: Please fill out the license field for your package! If it is unknown,
# then please put 'unknown'.

# Maintainer: Future Linux Team <future_linux@163.com>
pkgname=(python-lxml python-lxml-docs)
pkgbase=python-lxml
pkgver=5.3.0
pkgrel=1
pkgdesc="Python3 binding for the libxml2 and libxslt libraries"
arch=('x86_64')
url="https://lxml.de"
license=('BSD' 'custom')
depends=('python' 'libxslt')
makedepends=(
    'python-build'
    'python-installer'
    'python-flit-core'
    'python-wheel'
    'python-pygments'
    'python-sphinx'
    'python-sphinx_rtd_theme'
    'python-cython'
)
source=(https://github.com/lxml/lxml/releases/download/${pkgbase#*-}-${pkgver}/${pkgbase#*-}-${pkgver}.tar.gz)
sha256sums=(4e109ca30d1edec1ac60cdbe341905dc3b8f55b16855e03a54aaf59e51ec8c6f)

build() {
    cd ${pkgbase#*-}-${pkgver}

    export LC_CTYPE=en_US.UTF-8

    python3 -m build -nw
    make html
}

package_python-lxml() {
    cd ${pkgbase#*-}-${pkgver}

    python3 -m installer -d ${pkgdir} dist/*.whl
}

package_python-lxml-docs() {
    pkgdesc="Python binding for the libxml2 and libxslt libraries (docs)"
    depends=()

    cd ${pkgbase#*-}-${pkgver}

    install -d ${pkgdir}/usr/share/doc/${pkgbase}
    cp -r doc/html ${pkgdir}/usr/share/doc/${pkgbase}
}