python-requests/PKGBUILD

# This is an example PKGBUILD file. Use this as a start to creating your own,
# and remove these comments. For more information, see 'man PKGBUILD'.
# NOTE: Please fill out the license field for your package! If it is unknown,
# then please put 'unknown'.

# Maintainer: Future Linux Team <future_linux@163.com>
pkgname=python-requests 
pkgver=2.32.3
pkgrel=1
pkgdesc="Python HTTP for Humans"
arch=('x86_64')
url="https://requests.readthedocs.io/"
license=('Apache-2.0')
depends=(
    'ca-certificates'
    'python-charset-normalizer'
    'python-idna'
    'python-urllib3'
)
makedepends=(
    'git'
    'python-build'
    'python-installer'
    'python-setuptools'
    'python-wheel')
source=(https://github.com/psf/requests/archive/v${pkgver}/${pkgname#*-}-${pkgver}.tar.gz
    ${pkgname#*-}-${pkgver}-use_system_certs-1.patch)
sha256sums=(f665576fc02d02e7b7f21630b915d70c14288f48decf76fad89b16a9f3975c42
    ec1c7a1aa466a6f8c0f51803879ee51451a015bd467ed85cbd506370b87f8936)

prepare() {
    cd ${pkgname#*-}-${pkgver}

    patch -Np1 -i ${srcdir}/${pkgname#*-}-${pkgver}-use_system_certs-1.patch
}

build() {
    cd ${pkgname#*-}-${pkgver}

    python3 -m build --wheel --no-isolation
}

package() {
    cd ${pkgname#*-}-${pkgver}

    python3 -m installer --destdir=${pkgdir} dist/*.whl
}