# This is an example PKGBUILD file. Use this as a start to creating your own,
# and remove these comments. For more information, see 'man PKGBUILD'.
# NOTE: Please fill out the license field for your package! If it is unknown,
# then please put 'unknown'.

# Maintainer: Future Linux Team <future_linux@163.com>
pkgname=sqlite
pkgver=3.45.2
_pkgver=$(printf "%i%.2i%.2i%.2i" ${pkgver//./ })
pkgrel=1
pkgdesc="A C library that implements an SQL database engine"
arch=('x86_64')
url="https://www.sqlite.org/"
license=('LicenseRef-Sqlite')
makedepends=('readline' 'zlib')
options=('!emptydirs')
source=(https://sqlite.org/2024/sqlite-autoconf-${_pkgver}.tar.gz
    https://sqlite.org/2024/sqlite-doc-${_pkgver}.zip)
sha256sums=(bc9067442eedf3dd39989b5c5cfbfff37ae66cc9c99274e0c3052dc4d4a8f6ae
    645fd1078a4a03cfe83bfccc380685cc5dcf7dd132a23f78fad4f660e40cf2c7)

build() {
    cd sqlite-autoconf-${_pkgver}

    export CFLAGS="${CFLAGS/_FORTIFY_SOURCE=3/_FORTIFY_SOURCE=2}"
    export CXXFLAGS="${CXXFLAGS/_FORTIFY_SOURCE=3/_FORTIFY_SOURCE=2}"

    ${CONFIGURE}	                              \
    	--disable-static                          \
    	--enable-fts{4,5}                         \
    	TCLLIBDIR=/usr/lib64/${pkgname}${pkgver}  \
    	CPPFLAGS="${CPPFLAGS}                     \
    	    -DSQLITE_ENABLE_COLUMN_METADATA=1     \
    	    -DSQLITE_ENABLE_UNLOCK_NOTIFY=1       \
    	    -DSQLITE_ENABLE_DBSTAT_VTAB=1         \
    	    -DSQLITE_SECURE_DELETE=1              \
    	    -DSQLITE_ENABLE_FTS3_TOKENIZER=1"

    make
}

package() {
    cd sqlite-autoconf-${_pkgver}

    make DESTDIR=${pkgdir} install

    install -v -m755 -d ${pkgdir}/usr/share/doc/${pkgname}-${pkgver}
    cp -v -R ${srcdir}/sqlite-doc-${_pkgver}/* ${pkgdir}/usr/share/doc/${pkgname}-${pkgver}
}