# This is an example PKGBUILD file. Use this as a start to creating your own,
# and remove these comments. For more information, see 'man PKGBUILD'.
# NOTE: Please fill out the license field for your package! If it is unknown,
# then please put 'unknown'.

# Maintainer: Future Linux Team <xhaa123@outlook.com>
pkgname=tk
pkgver=8.6.15
pkgrel=1
pkgdesc="A windowing toolkit for use with tcl"
arch=('x86_64')
url="http://tcl.sourceforge.net"
license=('TCL')
depends=('tcl' 'libxscrnsaver' 'libxft')
source=(https://downloads.sourceforge.net/sourceforge/tcl/${pkgname}${pkgver}-src.tar.gz
    font-sizes.diff)
sha256sums=(550969f35379f952b3020f3ab7b9dd5bfd11c1ef7c9b7c6a75f5c49aca793fec
    80a64f81a002ca83475ac2e53b8c9836e1a376049989733b61687c88df8c68e5)

prepare() {
    cd ${pkgname}${pkgver}

    patch -Np1 -i ${srcdir}/font-sizes.diff
}

build() {
    cd ${pkgname}${pkgver}/unix

    ${CONFIGURE}                 \
        --enable-threads         \
        --disable-rpath          \
        --enable-64bit           \
        --mandir=/usr/share/man  \
        TK_LIBRARY=/usr/lib64/${pkgname}${pkgver%.*}

    make
}

package() {
    cd ${pkgname}${pkgver}/unix

    make INSTALL_ROOT=${pkgdir} install install-private-headers

    ln -sf wish${pkgver%.*} ${pkgdir}/usr/bin/wish
    ln -sf libtk${pkgver%.*}.so ${pkgdir}/usr/lib64/libtk.so

    # install private headers (FS#14388, FS#47616)
    cd ..
    for dir in compat generic generic/ttk unix; do
        install -dm755 ${pkgdir}/usr/include/tk-private/${dir}
        install -m644 -t ${pkgdir}/usr/include/tk-private/${dir} ${dir}/*.h
    done
    
    # remove buildroot traces
    sed -e "s#${srcdir}/${pkgname}${pkgver}/unix#/usr/lib64#" \
        -e "s#${srcdir}/${pkgname}${pkgver}#/usr/include#"    \
        -i ${pkgdir}/usr/lib64/tkConfig.sh
}